NOTE -- EXTENDED COMMAND FILE LABEL.CMD
USE &FILE1
GO TOP
STORE 2 TO LINE
STORE ' ' TO B:REF
STORE 'Y' TO CONTINUE
STORE '                                        ' TO M:NAME
STORE '    ' TO REF
ERASE
@  2,17 SAY "******************************************************"
@  3,17 SAY "*                                                    *"
@  4,17 SAY "* This program will type on 1 1/2 x 4 inch pregummed *"
@  5,17 SAY "* tractorfeed labels (1) the file owner's name,  (2) *"
@  6,17 SAY "* the alphanumeric number under which the article is *"
@  7,17 SAY "* stored,  and  (3) the  key words  under  which the *"
@  8,17 SAY "* article is referenced.                             *"
@  9,17 SAY "*                                                    *"
@ 10,17 SAY "******************************************************"
@ 14,22 SAY '** DO YOU WANT TO CONTINUE? (Y/N) **'
@ 22,1  SAY ' '
WAIT TO CONTINUE
IF !(CONTINUE)='N'
   RETURN
ENDIF
@ 14,22 SAY '                                     '
@ 23,0  SAY '                                '
@ 14,9  SAY "ENTER FILE OWNER'S NAME " GET M:NAME ;
   PICTURE 'XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX'
@ 16,11 SAY 'ENTER LETTER OF REFERENCE NUMBER FOR WHICH YOU WANT LABELS ';
   GET B:REF PICTURE 'X'
READ
@ 18,19 SAY 'ENTER NUMBER OF LAST '+!(B:REF)+'-ARTICLE LABELED ' GET REF;
   PICTURE '9999'
READ
@ 20,27 SAY '** PRINTER READY? (Y/N) **'
@ 22,1  SAY ' '
WAIT TO CONTINUE
IF !(CONTINUE)='N'
   RETURN
ENDIF
@ 20,27 SAY '                                     '
@ 23,0  SAY '                                '
@ 20,29 SAY '** LOCATING RECORDS **'
LOCATE FOR !(B:REF)$REF:NO .AND. !(REF)$REF:NO
SET FORMAT TO PRINT
SET EJECT OFF
DO WHILE .NOT. EOF
     STORE $(KWORDS,1,40) TO KW1
     STORE $(KWORDS,41,40) TO KW2
     @ LINE,17 SAY M:NAME USING 'XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX'
     STORE LINE+2 TO LINE
     @ LINE,1 SAY 'REF. NO.: '+REF:NO USING 'XXXXXXXXXXXXXXX'
     STORE LINE+1 TO LINE
     @ LINE,1 SAY KW1
     IF KW2<>' '
          STORE LINE+1 TO LINE
          @ LINE,1 SAY KW2
          STORE LINE+5 TO LINE
     ENDIF
     IF KW2=' '
          STORE LINE+6 TO LINE
     ENDIF
     CONTINUE
ENDDO
@ LINE+1,1 SAY ' '
RELEASE B:REF,REF,M:NAME,CONTINUE
SET FORMAT TO SCREEN
RETURN